Remote Sounds

// Control a ISD1820 module by remote using Arduino and a TSOP4838 IR Receiver module
// By keuwlsoft:  www.keuwl.com  4th Apr 2019
// cc Attribution-ShareAlike
//
// This sketch will receive an IR Pattern, Decode the Address and Command (JVC Protocol).
// Then if data valid and address matches, will use a switch case to action the command. 
// Controls a ISD1820 module using Arduino pins 8 to 10 which connect to the PLAYE, PLAYL and REC. 
// The TSOP4838 IR module is plugged straight into pins 2 to 4, using pins 3 and 4 to power it.
// An Interrupt is used to gather the IR Pattern timing, which is later analysed, thus keeping the main loop free for other tasks.
// Keuwlsofts 'IR Remote Creator' App was used to send the IR signal.
// The Remote and explanation can be found at www.keuwl.com/electronics/rduino/ir/04-remote-sounds/

int ir_pin=2; //use pins 2 or 3 for external interrupts, connect the IR receiver module output here.
int gnd_pin=3; //ground pin for the TSOP4838
int vcc_pin=4; //vcc pin for the TSOP4838
int playe_pin=8;
int playl_pin=9;
int rec_pin=10;

boolean recording=false; //flag to indicate if IRD1820 currently recording sound
boolean playing=false; //flag to indicate if IRD1820 currently playing sound with PLAYL method

long no_change_time=10000; //No change in IR pin for this duration (microseconds) will mark the end of pattern.
const int array_size=100; //Max times to log.  If array is full, it will report the pattern to that point. 
long t_array[array_size]; //Array of times of when the IR pin changes state.
int count=0; // Number of times logged to array.
boolean log_micros=true;  //Flag to indicate if able to log times to array
long last_micros=0; //previous array time entry

int addr=0; //Device address decoded from IR pattern
int cmmd=0; //Command decoded from IR pattern
int our_device_addr=0; //integer (0-255) that is an address to identify our device amoungst other devices.
boolean new_data=false; //Flag that is set everytime a new IR command is received


void setup() {
  pinMode(ir_pin, INPUT);

  //attach an interupt to log when the IR pin changes state
  attachInterrupt(digitalPinToInterrupt(ir_pin),interupt,CHANGE);

  //Supply power to TSOP4838 (Uses upto approx 1.5mA)
    pinMode(gnd_pin, OUTPUT);
    pinMode(vcc_pin, OUTPUT);
    digitalWrite(gnd_pin,LOW);
    digitalWrite(vcc_pin,HIGH);

 //Set pins connected to the IRD1820 board as outputs
    pinMode(playe_pin, OUTPUT);
    pinMode(playl_pin, OUTPUT);
    pinMode(rec_pin, OUTPUT);
    
}

void loop() {
  
//=========================================== Extract IR Command
  if (count>0){
    if (!log_micros|((micros()-last_micros)>no_change_time)){
      log_micros=false; //make sure array not modified while we analyse it
      //Get Pattern  
      count--;
      for (int i=0;i<count;i++){
        t_array[i]=t_array[i+1]-t_array[i];
      }
      //Extract Command And Address of JVC protocol
      if (count>=32){ //Check patten long enough for 16 bits of data
        int pos=count;
        // Extract Command 
        cmmd=0x00;
        for (int i=0;i<8;i++){
          cmmd=cmmd<<1; pos-=2;
          if (t_array[pos]>1000)cmmd=cmmd|1;
        }
        //Extract Address
        addr=0x00;
        for (int i=0;i<8;i++){
          addr=addr<<1; pos-=2;
          if (t_array[pos]>1000)addr=addr|1;
        }
        //check if data was for our device
        if (addr==our_device_addr) new_data=true;
      }  
  
    log_micros=true; count=0; //Reset array so another IR pattern can be received
    }
  }
//===========================================


//=========== Do Something with the Newly Received Command
  if (new_data){
    switch(cmmd){
      case 1: // PLAYE (Play complete recording on ISD1820)
        clear_isd1820(); //clear any current PLAYL or REC operation
        digitalWrite(playe_pin,HIGH);
        delay(10); 
        digitalWrite(playe_pin,LOW);
      break;
      case 2: //PLAYL (Start playing recording on ISD1820)
        clear_isd1820(); //clear any current PLAYL or REC operation
        digitalWrite(playl_pin,HIGH);
        playing=true;
      break;
      case 3: //PLAYL (Stop playing recording) 
        digitalWrite(playl_pin,LOW);
        playing=false;
     break;
      case 4: //Start recording sound on ISD1820
       clear_isd1820(); //clear any current PLAYL or REC operation
       digitalWrite(rec_pin,HIGH);
       recording=true;
      break;
      case 5: //Stop Recording
        digitalWrite(rec_pin,LOW);
        recording=false;
      break;
      
      default:
      break;
    }
    new_data=false;
  }
//===========

  delay(10); 
}

// clear any current recording/playing operation on the IRD1820 so ready to accept new command
void clear_isd1820(){
  if (recording){
    digitalWrite(rec_pin,LOW);
    recording=false;
    delay(100);
  }
  if (playing){
    digitalWrite(playl_pin,LOW);
    playing=false;
    delay(100);
  }
}

  
//========================================================
// Interupt to log each time the IR signal changes state 
void interupt(){
  if (log_micros){
    long m=micros();
    if (count>0&&(m-last_micros)>no_change_time){
      log_micros=false;
    }else{
       t_array[count]=m;
       count++;
       last_micros=m;
       if (count>=array_size) log_micros=false;
     }
  }
}
//========================================================