Color Changing LED

// IR Controlled Color Changing LED
// By keuwlsoft:  www.keuwl.com  16th Feb 2019
// cc Attribution-ShareAlike
//
// This sketch will receive an IR Pattern, Decode the Address and Command (NEC Protocol) and then apply a change
// to an RGB LED's color based on the command received.
// An Interrupt is used to gather the IR Pattern timing, which is later analysed, thus keeping the main loop free for other tasks.
// Keuwlsofts 'IR Remote Creator' App was used to send the IR signal. 
// The Remote can be downloaded at www.keuwl.com/electronics/rduino/ir/01-tricolor-led/


int ir_pin=2; //use pins 2 or 3 for external interupts, connect the IR sensor output here.

long no_change_time=10000; //No change in IR pin for this duration (microseconds) will mark the end of pattern.
const int array_size=100; //Max times to log.  If array is full, it will report the pattern to that point. 
long t_array[array_size]; //Array of times of when the IR pin changes state.
int count=0; // Number of times logged to array.
boolean log_micros=true;  //Flag to indicate if able to log times to array
long last_micros=0; //previous array time entry

int addr=0; //Device address decoded from IR pattern
int cmmd=0; //Command decoded from IR pattern
int our_device_addr=0; //integer (0-255) that is an address to identify our device amoungst other devices.

int Red_LED_Pin = 9; // PWM Pin for Red LED
int Green_LED_Pin = 10; // PWM Pin for Green LED
int Blue_LED_Pin = 11; // PWM Pin for Blue LED

//Varibles to hold brightness values ranging from 0 (off) to 255 (fully on)
int Red_value=0;
int Green_value=255;
int Blue_value=0;

boolean new_data=false; //Flag that is set everytime a new IR command is received
boolean LED_on=true; //Flag to indicate if LED is on
boolean Rotate=false; //Flag to indicate if color rotation is on
int Rotate_section=0; //Color rotation is divided into 6 sections.
int Rotate_step=4; //How much to change color each update.  Decrease for slower color rotation.
 

void setup() {

  pinMode(ir_pin, INPUT);

  //attach an interupt to log when the IR pin changes state
  attachInterrupt(digitalPinToInterrupt(ir_pin),interupt,CHANGE);
   
  // Initialise LED pins as outputs
  pinMode(Red_LED_Pin, OUTPUT);
  pinMode(Green_LED_Pin, OUTPUT);
  pinMode(Blue_LED_Pin, OUTPUT);

}

void loop() {
  
//=========================================== Extract IR Command
  if (count>0){
    if (!log_micros|((micros()-last_micros)>no_change_time)){
      log_micros=false; //make sure array not modified while we analyse it
      //Get Pattern  
      count--;
      for (int i=0;i<count;i++){
        t_array[i]=t_array[i+1]-t_array[i];
      }
      //Extract Command And Address of NEC protocol
      if (count>=64){ //Check patten long enough for 32 bits of data
        int pos=count;
        // Extract Command Compliment
        int cmmd2=0x00;
        for (int i=0;i<8;i++){
          cmmd2=cmmd2<<1; pos-=2;
           if (t_array[pos]>1000)cmmd2=cmmd2|1;
        }
        // Extract Command 
        cmmd=0x00;
        for (int i=0;i<8;i++){
          cmmd=cmmd<<1; pos-=2;
          if (t_array[pos]>1000)cmmd=cmmd|1;
        }
        //Extract Address Complement
        int addr2=0x00;
        for (int i=0;i<8;i++){
          addr2=addr2<<1; pos-=2;
          if (t_array[pos]>1000)addr2=addr2|1;
        }
        //Extract Address
        addr=0x00;
        for (int i=0;i<8;i++){
          addr=addr<<1; pos-=2;
          if (t_array[pos]>1000)addr=addr|1;
        }
    
        //check if data was for our device and is valid
        if ((addr2&addr)==0&&(addr2&addr)==0){
          if (addr==our_device_addr) new_data=true;
        }
      }  
  
    log_micros=true; count=0; //Reset array so another IR pattern can be received
    }
  }
//===========================================


//=========== Do Something with the Newly Received Command
  if (new_data){
    if (cmmd==1) LED_on=false; //Turn LED Off
    if (cmmd==2) LED_on=true; //Turn LED On
    if (cmmd==3){ // Increase Red Component
      Red_value+=16; Rotate=false;
      if (Red_value>255) Red_value=255;
    }
    if (cmmd==4){ // Decrease Red Component
      Red_value-=16; Rotate=false;
      if (Red_value<0) Red_value=0;
    }
    if (cmmd==5){ // Increase Green Component
      Green_value+=16; Rotate=false;
      if (Green_value>255) Green_value=255;
    }
    if (cmmd==6){ // Decrease Green Component
      Green_value-=16; Rotate=false;
      if (Green_value<0) Green_value=0;
    }
    if (cmmd==7){ // Increase Blue Component
      Blue_value+=16; Rotate=false;
      if (Blue_value>255) Blue_value=255;
    }
    if (cmmd==8){ // Decrease Blue Component
      Blue_value-=16; Rotate=false;
      if (Blue_value<0) Blue_value=0;
    }
    if (cmmd==9) Rotate=!Rotate; //Play (Rotate Colors)
    if (cmmd==10){ //Orange
      Red_value=180; Green_value=135; Blue_value=0; Rotate=false;
    }
     if (cmmd==11){ //Pink
      Red_value=200; Green_value=70; Blue_value=100; Rotate=false;
    }
    if (cmmd==12){ //White
      Red_value=255; Green_value=255; Blue_value=255; Rotate=false;
    }
    if (cmmd==13){ //Red
       Red_value=255; Green_value=0; Blue_value=0; Rotate=false;
    }
    if (cmmd==14){ //Green
       Red_value=0; Green_value=255; Blue_value=0; Rotate=false;
    }
    if (cmmd==15){ //Blue
       Red_value=0; Green_value=0; Blue_value=255; Rotate=false;
    }
    new_data=false;
  }
//===========


//=========== Rotating Color Effect
  if (Rotate){
    if (Rotate_section==0){ //Increase Green
      Green_value+=Rotate_step;
      if (Green_value>=255){
        Green_value=255; Rotate_section++;
      }
    }else if (Rotate_section==1){ //Decrease Red;
      Red_value-=Rotate_step;
      if (Red_value<=0){
        Red_value=0; Rotate_section++;
      }
    }else if (Rotate_section==2){ //Increase Blue
      Blue_value+=Rotate_step;
      if (Blue_value>=255){
        Blue_value=255; Rotate_section++;
      }
    }else if (Rotate_section==3){ //Decrease Green
      Green_value-=Rotate_step;
      if (Green_value<=0){
        Green_value=0; Rotate_section++;
      }
    }else if (Rotate_section==4){ //Increase Red
       Red_value+=Rotate_step;
       if (Red_value>=255){
         Red_value=255; Rotate_section=0;
       }
    }else if (Rotate_section==5){ //Decrease Blue
       Blue_value-=Rotate_step;
       if (Blue_value<=0){
         Blue_value=0; Rotate_section++;
       }
    }
  }
//===========  


//=========== Update LED Brightness
  if (LED_on){
    analogWrite(Red_LED_Pin, Red_value);
    analogWrite(Green_LED_Pin, Green_value);
    analogWrite(Blue_LED_Pin, Blue_value);
  }else{
    analogWrite(Red_LED_Pin, 0);
    analogWrite(Green_LED_Pin, 0);
    analogWrite(Blue_LED_Pin, 0);
  }
//=========== 
  
  delay(10);
}

  
//========================================================
// Interupt to log each time the IR signal changes state 
void interupt(){
  if (log_micros){
    long m=micros();
    if (count>0&&(m-last_micros)>no_change_time){
      log_micros=false;
    }else{
       t_array[count]=m;
       count++;
       last_micros=m;
       if (count>=array_size) log_micros=false;
     }
  }
}
//========================================================